Pushing Buttons

• Get Browser Function in ASP

  0 Comments Posted on September 23rd, 2009          Updated on September 23rd, 2009 Tagged in ASPVBScript

  In an earlier post I explained how to create a custom function in PHP to retrieve visitor browser information. The same can be done in ASP.
  
  Function getBrowser()
     Dim regex, hits : Set regex = New regexp : regex.Global = True : regex.IgnoreCase = True
     Dim versmatch : versmatch = "(\);)?(\w*[\/|\s|-]\d+[\.\w]*(\s\[\w+\])?(\sMobile)?)?"
     Dim check, checks, agent : agent = Request.ServerVariables("HTTP_USER_AGENT")
     Set checks = server.createobject("Scripting.Dictionary")
     With checks
          .add "AOL", "(AOL)"
          .add "Avant Browser", "(Avant Browser)"
          .add "MSIE", "(IE)"
          .add "Chrome", "(Chrome)"
          .add "Navigator", "(Netscape|Navigator)"
          .add "Iceweasel", "(Iceweasel)"
          .add "SeaMonkey", "(SeaMonkey)"
          .add "Firefox", "(Firefox)"
          .add "Safari", "(Version|Safari)"
          .add "Nintendo Wii", "(Opera)"
          .add "Opera", "(Opera)"
          .add "Firebird", "(Firebird)"
          .add "Kazehakase", "(Kazehakase)"
          .add "Iceape", "(Iceape)"
          .add "Phoenix", "(Phoenix)"
          .add "Playstation 3", "(Playstation 3)"
          .add "PSP", "(Playstation Portable)"
          .add "Googlebot", "(Googlebot)"
          .add "msnbot", "(msnbot-Products|msnbot)"
          .add "Yahoo! Slurp China", "(Yahoo! Slurp China)"
          .add "Yahoo! Slurp", "(Yahoo! Slurp)"
          .add "Ask Jeeves", "(Ask Jeeves)"
          .add "Cuil", "(Twiceler)"
          .add "Mozilla", "(Mozilla)"
          .add "BlackBerry", "(BlackBerry)"
     End With

     getBrowser = "unknown"
     For Each check IN checks
          regex.Pattern = check
          Set hits = regex.Execute(agent)
          if hits.count > 0 then
               regex.Pattern = checks.item(check) & versmatch
               Set hits = regex.Execute(agent)
               getBrowser = replace(replace(replace(hits.item(0), "/", " "), ");", ""), "-", " ")
               Select Case check
                    Case "Safari"
                         getBrowser = replace(getBrowser, "Version", "Safari")
                    Case "Navigator"
                         getBrowser = replace(getBrowser, "Navigator", "Netscape")
                    Case "msnbot"
                         getBrowser = replace(getBrowser, "Products", "")
                         getBrowser = replace(getBrowser, "msnbot", "Windows Live")
                    Case "Cuil"
                         getBrowser = replace(getBrowser, "Twiceler", "Cuil")
                    Case "Nintendo Wii"
                         getBrowser = replace(getBrowser, "Opera", "Nintendo Wii (Opera)")
                    Case "BlackBerry"
                         getBrowser = replace(getBrowser, "BlackBerry", "BlackBerry ")
               End Select
               Exit For
          End If
     Next
End Function

Leave a Comment

• You Sep 7, 2010
  Add Comment